VB.NET Exception.Data属性代码示例

OGeek|极客世界-中国程序员成长平台 › 门户 › 编程› VB.NET›VB.NET教程

原作者: [db:作者] 来自: [db:来源] 收藏邀请

本文整理汇总了VB.NET中System.Exception.Data属性的典型用法代码示例。如果您正苦于以下问题：VB.NET Exception.Data属性的具体用法？VB.NET Exception.Data怎么用？VB.NET Exception.Data使用的例子？那么恭喜您, 这里精选的属性代码示例或许可以为您提供帮助。您也可以进一步了解该属性所在类System.Exception的用法示例。

在下文中一共展示了Exception.Data属性的1个代码示例，这些例子默认根据受欢迎程度排序。您可以为喜欢或者感觉有用的代码点赞，您的评价将有助于我们的系统推荐出更棒的VB.NET代码示例。

示例1: Example

' 导入命名空间
Imports System.Collections

Module Example
   Public Sub Main()
      Console.WriteLine()
      Console.WriteLine("Exception with some extra information...")
      RunTest(False)
      Console.WriteLine()
      Console.WriteLine("Exception with all extra information...")
      RunTest(True)
   End Sub

   Public Sub RunTest(displayDetails As Boolean)
      Try
         NestedRoutine1(displayDetails)
      Catch e As Exception
         Console.WriteLine("An exception was thrown.")
         Console.WriteLine(e.Message)
         If e.Data.Count > 0 Then
            Console.WriteLine("  Extra details:")
            For Each de As DictionaryEntry In e.Data
               Console.WriteLine("    Key: {0,-20}      Value: {1}",
                                 "'" + de.Key.ToString() + "'", de.Value)
            Next
         End If 
      End Try 
   End Sub 

   Public Sub NestedRoutine1(displayDetails As Boolean)
      Try
         NestedRoutine2(displayDetails)
      Catch e As Exception
         e.Data("ExtraInfo") = "Information from NestedRoutine1."
         e.Data.Add("MoreExtraInfo", "More information from NestedRoutine1.")
         Throw e
      End Try 
   End Sub

   Public Sub NestedRoutine2(displayDetails As Boolean)
      Dim e As New Exception("This statement is the original exception message.")
      If displayDetails Then 
         Dim s As String = "Information from NestedRoutine2." 
         Dim i As Integer = -903
         Dim dt As DateTime = DateTime.Now
         e.Data.Add("stringInfo", s)
         e.Data("IntInfo") = i
         e.Data("DateTimeInfo") = dt
      End If 
      Throw e
   End Sub 
End Module

开发者ID:VB.NET开发者，项目名称:System，代码行数:52，代码来源:Exception.Data

输出：

Exception with some extra information...
An exception was thrown.
This statement is the original exception message.
Extra details:
Key: 'ExtraInfo'               Value: Information from NestedRoutine1.
Key: 'MoreExtraInfo'           Value: More information from NestedRoutine1.

Exception with all extra information...
An exception was thrown.
This statement is the original exception message.
Extra details:
Key: 'stringInfo'              Value: Information from NestedRoutine2.
Key: 'IntInfo'                 Value: -903
Key: 'DateTimeInfo'            Value: 7/29/2013 10:50:13 AM
Key: 'ExtraInfo'               Value: Information from NestedRoutine1.
Key: 'MoreExtraInfo'           Value: More information from NestedRoutine1.

注：本文中的System.Exception.Data属性示例整理自Github/MSDocs等源码及文档管理平台，相关代码片段筛选自各路编程大神贡献的开源项目，源码版权归原作者所有，传播和使用请参考对应项目的License；未经允许，请勿转载。