vb.net - Random numbers in array without any duplicates

Question

I'm trying to randomize an array from numbers 0 to 51 using loops but I just cannot seem to pull it off. My idea was that

1. Generate a Random Number
2. Check if this random number has been used by storing the previous in an array
3. If this random number has been used, generate new random number until it is not a duplicate
4. If it's not a duplicate, store it

My attempt:

    Dim list(51) As Integer
    Dim templist(51) As Integer

    For i As Integer = 0 To 51 Step 1
        list(i) = i
    Next i

    Do While counter <= 51
        p = rand.Next(0, 52)
        templist(counter) = p
        For n As Integer = 0 To 51 Step 1
            p = rand.Next(0, 52)
            If templist(n) = p Then
                Do While templist(n) = p
                    p = rand.Next(0, 52)
                Loop
                templist(n) = p
            Else
                templist(n) = p
            End If

        Next

        counter += 1
    Loop

    For n As Integer = 0 To 51 Step 1
        ListBox1.Items.Add(templist(n))
    Next

Answer 1

It will be a lot easier if you just have a list of all of the possible numbers (0 to 51 in your case), then remove the number from the list so it can't be picked again. Try something like this:

Dim allNumbers As New List (Of Integer)
Dim randomNumbers As New List (Of Integer)
Dim rand as New Random

' Fill the list of all numbers
For i As Integer = 0 To 51 Step 1
    allNumbers.Add(i)
Next i

' Grab a random entry from the list of all numbers
For i As Integer = 0 To 51 Step 1
    Dim selectedIndex as Integer = rand.Next(0, (allNumbers.Count - 1) )
    Dim selectedNumber as Integer = allNumbers(selectedIndex)
    randomNumbers.Add(selectedNumber)
    allNumbers.Remove(selectedNumber)
    ' Might as well just add the number to ListBox1 here, too
    ListBox1.Items.Add(selectedNumber)
Next i

If your goal is to get the numbers into ListBox1, then you don't even need the "randomNumbers" list.

EDIT:

If you must have an array, try something like this:

Function RandomArray(min As Integer, max As Integer) As Integer()

    If min >= max Then
        Throw New Exception("Min. must be less than Max.)")
    End If

    Dim count As Integer = (max - min)
    Dim randomNumbers(count) As Integer
    Dim rand As New Random()

    ' Since an array of integers sets every number to zero, and zero is possibly within our min/max range (0-51 here),
    ' we have to initialize every number in the array to something that is outside our min/max range.
    If min <= 0 AndAlso max >= 0 Then
        For i As Integer = 0 To count
            randomNumbers(i) = (min - 1)    ' Could also be max + 1
        Next i
    End If

    Dim counter As Integer = 0
    ' Loop until the array has count # of elements (so counter will be equal to count + 1, since it is incremented AFTER we place a number in the array)
    Do Until counter = count + 1
        Dim someNumber As Integer = rand.Next(min, max + 1)
        ' Only add the number if it is not already in the array
        If Not randomNumbers.Contains(someNumber) Then
            randomNumbers(counter) = someNumber
            counter += 1
        End If
    Loop

    Return randomNumbers
End Function

This is good enough for your assignment, but the computer scientist in my hates this algorithm.

Here's why this algorithm is much less desirable. If zero is in your range of numbers, you will have to loop through the array at least 2N times (so 104+ times if you are going from 0 to 51). This is a best case scenario; the time complexity of this algorithm actually gets worse as the range of numbers scales higher. If you try running it from 0 to 100,000 for example, it will fill the first few thousand numbers very quickly, but as it goes on, it will take longer and longer to find a number that isn't already in the list. By the time you get to the last few numbers, you could potentially have randomly generated a few trillion different numbers before you find those last few numbers. If you assume an average complexity of 100000! (100,000 factorial), then the loop is going to execute almost ten to the half-a-millionth power times.

An array is more difficult to "shuffle" because it is a fixed size, so you can't really add and remove items like you can with a list or collection. What you CAN do, though, is fill the array with your numbers in order, then go through a random number of iterations where you randomly swap the positions of two numbers.