recursion - How do you write a fun that's recursive in Erlang?

Question

I'm trying to write a recursive fun in an Erlang shell, but I keep getting an unbound variable exception:

1> Foo = fun(X) -> Foo(X) end.
* 1: variable 'Foo' is unbound

This probably goes without saying, but I'm not trying to create an infinite loop! This is just a simple example of the error I'm getting.

question from:https://stackoverflow.com/questions/867418/how-do-you-write-a-fun-thats-recursive-in-erlang

Answer 1

You can do it with a little argument trick:

1> Foo = fun(F, X) -> F(F, X) end.
#Fun<erl_eval.12.113037538>
2> Foo(Foo, a).
<...infinite loop!>

The trick here is to send in the function as an argument to itself to allow recursion.

Alternative way to make it in one shoot:

1> Foo = fun(X) -> Fun = fun(F,Y) -> F(F,Y) end, Fun(Fun,X) end.
#Fun<erl_eval.6.13229925>
2> Foo(a).

For example:

1> Foo = fun(Max) ->
1>     Fun = fun(F, X) when X > Max -> [];
1>              (F, X) -> [X | F(F, X+1)]
1>           end,
1>     Fun(Fun, 0)
1> end.
#Fun<erl_eval.6.13229925>
2> Foo(10).
[0,1,2,3,4,5,6,7,8,9,10]

Since OTP 17.0 there are named funs which makes the task a lot easier:

1> Perms = fun F([]) -> [[]]; F(L) -> [[H|T] || H <- L, T <- F(L--[H])] end.    
#Fun<erl_eval.30.54118792>
2> Perms([a,b,c]).
[[a,b,c],[a,c,b],[b,a,c],[b,c,a],[c,a,b],[c,b,a]]